Программирование с использованием переменных типа запись в delphi

22. Дана строка символов, содержащая некоторый текст на русском языке. Разработать программу форматирования этого текста, т. е. его разбиения на отдельные строки ( по k символов в каждой строке ) и выравнивания по правой границе путем вставки между отдельными словами необходимого количества пробелов.

23. Дана строка символов, содержащая некоторый текст на русском языке. Заменить буквы русского алфавита на соответствующие им буквы латинского алфавита.

24. Дана строка символов, содержащая некоторый текст. Разработать программу, которая определяет, является ли данный текст палиндромом, т. е. читается ли он слева направо так же, как и справа налево ( например, «А роза упала на лапу Азора»).

25. Составить программу, которая читает построчно текст другой программы ( ввести с клавиатуры ) на языке Pascal, обнаруживает комментарии и выводит их на экран.

26. Составить программу, которая читает построчно текст другой программы ( ввести с клавиатуры ) на языке Pascal, подсчитывает количество ключевых слов «begin» и «end» и выводит на экран соответствующее сообщение.

27. Разработать программу, которая заданное целое число от 1 до 1999 выводит на экран римскими цифрами.

28. Дан текст из заглавных латинских букв, за которым следует пробел. Определить, является ли этот текст правильной записью римскими цифрами целого числа от 1 до 999, и, если является, вывести на экран это число арабскими цифрами( в десятичной системе).

29. Дан текст из k символов. Вывести на экран только строчные русские буквы, входящие в этот текст.

30. Дан текст из k символов. Вывести на экран в алфавитном порядке все различные прописные русские буквы, входящие в этот текст.

Тема 6. Программирование с использованием записей и файлов

Цель лабораторной работы: изучить правила работы с компонентами TOpenDialog и TSaveDialog. Написать программу с использованием файлов и данных типа запись.

6.1. Программирование с использованием переменных типа запись

Запись – это структура данных, объединяющая элементы одного или различных типов, называемые полями. Записи удобны для создания структурированных баз данных с разнотипными элементами, например:

Type {Объявление типа запись}

TStudent = record

Fio: string[20]; {Поле ф. и.о.}

Group: integer; {Поле номера студ. группы}

Ocn: array[1..3] of integer; {Поле массива оценок}

end;

Var

Student: TStudent; {Объявление переменной типа запись}

Доступ к каждому полю осуществляется указанием имени записи и поля, разделенных точкой, например:

Student. Fio:= ‘Иванов А. И.’; {Внесение данных в поля записи}

Student. Group:=720603;

. . .

Доступ к полям можно осуществлять также при помощи оператора with:

With Student do

Begin

Fio:= ‘Иванов А. И.’;

Group:=720603;

End;

6.2. Работа с файлами

Файл – это именованная область данных на внешнем физическом носителе. В Object Pascal различают три вида файлов в зависимости от способа их организации и доступа к элементам: текстовые, типизированные и нетипизированные.

Текстовой файл – это файл, состоящий из строк. Примером текстового файла может служить файл исходного текста программы в DELPHI (расширение *.pas). Для работы с текстовым файлом должна быть описана соответствующая файловая переменная: Var F: TextFile;.

Типизированные файлы имеют строго заданную их описанием структуру, когда все элементы имеют фиксированный и одинаковый размер. Это свойство типизированных файлов позволяет получить доступ к любому компоненту файла по его порядковому номеру. Элементами такого файла являются, как правило, записи. В описании файловой переменной указывается ее тип: Var F: TStudent;.

Нетипизированный файл – это файл, в котором данные не имеют определенного типа и рассматриваются как последовательность байт. Файловая переменная объявляется: Var F: File;.

Порядок работы с файлами следующий:

. . .

AssignFile(F, ‘Filename. txt’); // Связывание файловой переменной F

// с именем дискового файла “Filename. txt”

Rewrite(F); // Создание нового или открытие (Reset(F);)

// уже существующего файла

. . .

Read(F, Stud); // Чтение данных из файла или

// запись (Write(F, Stud)) в файл

. . .

CloseFile(F); // Закрытие файла

6.3. Подпрограммы работы с файлами

AssignFile(var F; FileName: string) — связывает файловую переменную F и файл с именем FileName.

Reset(var F[: File; RecSize: word]) — открывает существующий файл. При открытии нетипизированного файла RecSize задает размер элемента файла.

Rewrite(var F[: File; RecSize: word]) — создает и открывает новый файл.

Append(var F: TextFile) — открывает текстовой файл для дописывания текста в конец файла.

Read(F, v1[,v2,…vn]) — чтение значений переменных начиная с текущей позиции для типизированных файлов и строк для текстовых.

Write(F, v1[,v2,…vn]) — запись значений переменных начиная с текущей позиции для типизированных файлов и строк для текстовых.

CloseFile(F) — закрывает ранее открытый файл.

Rename(var F; NewName: string) — переименовывает неоткрытый файл любого типа.

Erase(var F) — удаляет неоткрытый файл любого типа.

Seek(var F; NumRec: Longint) — для нетекстового файла устанавливает указатель на элемент с номером NumRec.

SetTextBuf(var F: TextFile; var Buf[;Size: word]) — для текстового файла устанавливает новый буфер ввода-вывода объема Size.

Flush(var F: TextFile) — немедленная запись в файл содержимого буфера ввода-вывода.

Truncate(var F) — урезает файл, начиная с текущей позиции.

LoResult: integer — код результата последней операции ввода-вывода.

FilePos(var F): longint — для нетекстовых файлов возвращает номер текущей позиции. Отсчет ведется от нуля.

FileSize(var F): longint — для нетекстовых файлов возвращает количество компонентов в файле.

Eoln(var F: TextFile): boolean — возвращает True, если достигнут конец строки.

Eof(var F) ): boolean — возвращает True, если достигнут конец файла.

SeekEoln(var F: TextFile): boolean – возвращает True, если пройден последний значимый символ в строке или файле, отличный от пробела или знака табуляции.

SeekEof(var F: TextFile): boolean — то же, что и SeekEoln, но для всего файла.

BlockRead(var F: File; var Buf; Count: word[; Result: word]) , BlockWrite(var F: File; var Buf; Count: word[; Result: word]) — соответственно процедуры чтения и записи переменной Buf с количеством Count блоков.

6.4. Компоненты TOpenDialog и TSaveDialog

Компоненты TOpenDialog и TSaveDialog находятся на странице DIALOGS (см. прил. 2). Все компоненты этой страницы являются невизуальными, т. е. не видны в момент работы программы. Поэтому их можно разместить в любом удобном месте формы. Оба рассматриваемых компонента имеют идентичные свойства и отличаются только внешним видом. После вызова компонента появляется диалоговое окно, с помощью которого выбирается имя программы и путь к ней. В случае успешного завершения диалога имя выбранного файла и маршрут поиска содержaтся в свойстве FileName. Для фильтрации файлов, отображаемых в окне просмотра, используется свойство Filter, а для задания расширения файла, в случае, если оно не задано пользователем, – свойство DefaultExt. Если необходимо изменить заголовок диалогового окна, используется свойство Title.

6.5. Порядок выполнения задания

Задание: написать программу, вводящую в файл или читающую из файла ведомость абитуриентов, сдавших вступительные экзамены. Каждая запись должна содержать фамилию, а также оценки по физике, математике и сочинению. Вывести список абитуриентов, отсортированный в порядке уменьшения их среднего балла, и записать эту информацию в текстовой файл.

6.5.1. Настройка компонентов TOpenDialog и TSaveDialog

Для установки компонентов TOpenDialog и TSaveDialog на форму необходимо на странице Dialogs меню компонентов щелкнуть мышью соответственно по пиктограммам или и поставить их в любое свободное место формы. Установка фильтра производится следующим образом. Выбрав соответствующий компонент, дважды щелкнуть по правой части свойства Filter инспектора объектов. Появится окно Filter Editor, в левой части которого записывается текст, характеризующий соответствующий фильтр, а в правой части – маску. Для OpenDialod1 установим значения маски как показано на рис. 6.1. Формат *.dat означает что, будут видны все файлы с расширением dat, а формат *.* — что будут видны все файлы (с любым именем и с любым расширением).

Для того, чтобы файл автоматически записывался с расширением. dat, в свойстве DefaultExt запишем требуемое расширение — .dat.

Аналогичным образом настроим SaveDialog1 для текстового файла (расширение. txt).

6.5.2. Работа с программой

После запуска программы на выполнение появится диалоговое окно программы. Кнопка “Ввести запись” видна не будет. Необходимо создать новый файл записей, нажав на кнопку “Создать” или открыть ранее созданный, нажав кнопку “Открыть”. После этого станет видна кнопка “Ввести запись” и можно будет вводить записи. При нажатии на кнопку “Сортировка” будет проведена сортировка ведомости по убыванию среднего балла и диалоговое окно примет вид как на рис. 6.2.. Затем при нажатии на кнопку “Сохранить” будет создан текстовой файл, содержащий отсортированную ведомость. Файл записей закрывается одновременно с программой при нажатии на кнопку “Close” или .

Текст программы приведен ниже.

unit tema6;

interface

uses

Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,

StdCtrls, Buttons, ExtCtrls;

type

TForm1 = class(TForm)

Edit1: TEdit;

Edit2: TEdit;

Edit3: TEdit;

Edit4: TEdit;

Label1: TLabel;

Label2: TLabel;

Label3: TLabel;

Label4: TLabel;

Label5: TLabel;

Memo1: TMemo;

Button1: TButton;

Button3: TButton;

Splitter1: TSplitter;

Button5: TButton;

BitBtn1: TBitBtn;

SaveDialog1: TSaveDialog;

Button2: TButton;

OpenDialog1: TOpenDialog;

Button4: TButton;

procedure FormCreate(Sender: TObject);

procedure Button1Click(Sender: TObject);

procedure Button2Click(Sender: TObject);

procedure Button3Click(Sender: TObject);

procedure Button4Click(Sender: TObject);

procedure Button5Click(Sender: TObject);

procedure BitBtn1Click(Sender: TObject);

procedure FormClose(Sender: TObject; var Action: TCloseAction);

private

{ Private declarations }

public

{ Public declarations }

end;

Type

TStudent = record

FIO: string[40]; // Поле ф. и.о.

otc: array[1..3] of word; // Поле массива оценок

sball : extended; // Поле среднего балла

end;

Var

Fz : file of Tstudent; // Файл типа запись

Ft : TextFile; // Текстовой файл

Stud : array[1..100] of Tstudent; // Массив записей

nzap : integer; // Номер записи

FileNameZ, FileNameT : string; // Имя файла

var

Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.FormCreate(Sender: TObject);

begin

Edit1.Text:=»;

Edit2.Text:=»;

Edit3.Text:=»;

Edit4.Text:=»;

Memo1.Clear;

Button1.Hide; // Сделать невидимой кнопку "Ввести запись"

nzap:=0;

end;

procedure TForm1.Button1Click(Sender: TObject); // Ввести новую запись

begin

nzap:=nzap+1;

with stud[nzap] do begin

FIO:=Edit1.Text;

otc[1]:=StrToInt(Edit2.Text);

otc[2]:=StrToInt(Edit3.Text);

otc[3]:=StrToInt(Edit4.Text);

sball:=(otc[1]+otc[2]+otc[3])/3;

Memo1.Lines. Add(fio+’ ‘+IntToStr(otc[1])+’ ‘+ IntToStr(otc[2])+’ ‘+IntToStr(otc[3]));

end;

Write(fz, Stud[nzap]); // Запись в файл

Edit1.Text:=»;

Edit2.Text:=»;

Edit3.Text:=»;

Edit4.Text:=»;

end;

procedure TForm1.Button2Click(Sender: TObject); // Создание нового файла записей

begin

OpenDialog1.Title :=’Создать новый файл’; // Изменение заголовка окна диалога

if OpenDialog1.Execute then // Выполнение стандартного диалога выбора имени файла

begin

FileNameZ:= OpenDialog1.FileName; // Возвращение имени дискового файла

AssignFile(Fz, FileNameZ); // Связывание файловой переменной Fz c именем файла

Rewrite(Fz); // Создание нового файла

end;

Button1.Show; // Сделать видимой кнопку "Ввести запись"

end;

procedure TForm1.Button3Click(Sender: TObject); // Открыть существующий файл

begin

if OpenDialog1.Execute then // Выполнение стандартного диалога выбора имени файла

begin

FileNameZ:= OpenDialog1.FileName; // Возвращение имени дискового файла

AssignFile(Fz, FileNameZ); // Связывание файловой переменной Fz c именем файла

Reset(Fz); // Открытие существующего файла

end;

while not eof(fz) do begin

nzap:=nzap+1;

Read(fz, stud[nzap]); // Чтение записи из файла

with stud[nzap] do

Memo1.Lines. Add(fio+’ ‘+IntToStr(otc[1])+’ ‘+IntToStr(otc[2])+’ ‘+IntToStr(otc[3]));

end;

Button1.Show; // Сделать видимой кнопку "Ввести запись"

end;

procedure TForm1.Button4Click(Sender: TObject); // Сортировка записей

var i, j : word;

st : TStudent;

begin

for i:=1 to nzap-1 do // Сортировка массива записей

for j:=i+1 to nzap do

if Stud[i].sball < Stud[j].sball then begin

st:=Stud[i];

Stud[i]:=Stud[j];

Stud[j]:=st;

end;

Memo1.Clear;

for i:=1 to nzap do // Вывод в окно Memo1 отсортированных записей

with stud[i] do

Memo1.Lines. Add(IntToStr(i)+’ ‘+fio+’ ‘+FloatToStrf(sball, fffixed,4,2));

end;

procedure TForm1.Button5Click(Sender: TObject); // Сохранение результатов сортировки // в текстовом файле

var i:word;

begin

if SaveDialog1.Execute then // Выполнение стандартного диалога выбора имени файла

begin

FileNameT:= SaveDialog1.FileName; // Возвращение имени дискового файла

AssignFile(Ft, FileNameT); // Связывание файловой переменной Ft c именем файла

Rewrite(Ft); // Открытие нового текстового файла

end;

for i:=1 to nzap do

with stud[i] do Writeln(Ft, i:4,’. ‘,fio, sball:8:2); // Запись в текстовой файл

CloseFile(Ft); // Закрытие текстового файла

end;

procedure TForm1.BitBtn1Click(Sender: TObject);

begin

CloseFile(fz); // Закрытие файла записей при нажатии на кнопку “Сlose”

end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);

begin

CloseFile(fz); // Закрытие файла записей при нажатии на кнопку

end;

end.

6.6.Выполнение индивидуального задания

В программе предусмотреть сохранение вводимых данных в файле и возможность чтения из ранее сохраненного файла. Результаты выводить в окно просмотра и в текстовой файл.

1. В магазине формируется список лиц, записавшихся на покупку товара повышенного спроса. Каждая запись этого списка содержит: порядковый номер, Ф. И.О., домашний адрес покупателя и дату постановки на учет. Удалить из списка все повторные записи, проверяя Ф. И.О. и домашний адрес.

2. Список товаров, имеющихся на складе, включает в себя наименование товара, количество единиц товара, цену единицы и дату поступления товара на склад. Вывести в алфавитном порядке список товаров, хранящихся больше месяца, стоимость которых превышает 1000000 руб.

3. Для получения места в общежитии формируется список студентов, который включает Ф. И.О. студента, группу, средний балл, доход на члена семьи. Общежитие в первую очередь предоставляется тем, у кого доход на члена семьи меньше двух минимальных зарплат, затем остальным в порядке уменьшения среднего балла. Вывести список очередности предоставления мест в общежитии.

4. В справочной автовокзала хранится расписание движения автобусов. Для каждого рейса указаны его номер, тип автобуса, пункт назначения, время отправления и прибытия. Вывести информацию о рейсах, которыми можно воспользоваться для прибытия в пункт назначения раньше заданного времени.

5. На междугородной АТС информация о разговорах содержит дату разговора, код и название города, время разговора, тариф, номер телефона в этом городе и номер телефона абонента. Вывести по каждому городу общее время разговоров с ним и сумму.

6. Информация о сотрудниках фирмы включает: Ф. И.О., табельный номер, количество проработанных часов за месяц, почасовой тариф. Рабочее время свыше 144 часов считается сверхурочным и оплачивается в двойном размере. Вывести размер заработной платы каждого сотрудника фирмы за вычетом подоходного налога, который составляет 12% от суммы заработка.

7. Информация об участниках спортивных соревнований содержит: наименование страны, название команды, Ф. И.О. игрока, игровой номер, возраст, рост, вес. Вывести информацию о самой молодой, рослой и легкой команде.

8. Для книг, хранящихся в библиотеке, задаются: регистрационный номер книги, автор, название, год издания, издательство, количество страниц. Вывести список книг с фамилиями авторов в алфавитном порядке, изданных после заданного года.

9. Различные цехи завода выпускают продукцию нескольких наименований. Сведения о выпущенной продукции включают: наименование, количество, номер цеха. Для заданного цеха необходимо вывести количество выпущенных изделий по каждому наименованию в порядке убывания количества.

10. Информация о сотрудниках предприятия содержит: Ф. И.О., номер отдела, должность, дату начала работы. Вывести списки сотрудников по отделам в порядке убывания стажа.

11. Ведомость абитуриентов, сдавших вступительные экзамены в университет, содержит: Ф. И.О., адрес, оценки. Определить количество абитуриентов, проживающих в г. Минске и сдавших экзамены со средним баллом не ниже 4.5, вывести их фамилии в алфавитном порядке.

12. В справочной аэропорта хранится расписание вылета самолетов на следующие сутки. Для каждого рейса указаны: номер рейса, тип самолета, пункт назначения, время вылета. Вывести все номера рейсов, типы самолетов и времена вылета для заданного пункта назначения в порядке возрастания времени вылета.

13. У администратора железнодорожных касс хранится информация о свободных местах в поездах дальнего следования на ближайшую неделю в следующем виде: дата выезда, пункт назначения, время отправления, число свободных мест. Оргкомитет международной конференции обращается к администратору с просьбой зарезервировать m мест до города N на k-й день недели с временем отправления поезда не позднее t часов вечера. Вывести время отправления или сообщение о невозможности выполнить заказ в полном объеме.

14. Ведомость абитуриентов, сдавших вступительные экзамены в университет, содержит: Ф. И.О. абитуриента, оценки. Определить средний балл по университету и вывести список абитуриентов, средний балл которых выше среднего балла по университету. Первыми в списке должны идти студенты, сдавшие все экзамены на 5.

15. В радиоателье хранятся квитанции о сданной в ремонт радиоаппаратуре. Каждая квитанция содержит следующую информацию: наименование группы изделий(телевизор, радиоприемник и т. п.),марку изделия, дату приемки в ремонт, состояние готовности заказа (выполнен, не выполнен). Вывести информацию о состоянии заказов на текущие сутки по группам изделий.

16. Разработать программу формирования ведомости об успеваемости студентов. Каждая запись этой ведомости должна содержать: номер группы, Ф. И.О. студента, оценки за последнюю сессию. Вывести списки студентов по группам. В каждой группе Ф. И.О. студентов должны быть расположены в порядке убывания среднего балла.

17. В исполкоме формируется список учета нуждающихся в улучшении жилищных условий. Каждая запись этого списка содержит: порядковый номер, Ф. И.О., величину жилплощади на одного члена семьи и дату постановки на учет. По заданному количеству квартир, выделяемых по данному списку в течение года, вывести весь список с указанием ожидаемого года получения квартиры.

18. Имеется список женихов и список невест. Каждая запись списка содержит пол, имя, возраст, рост, вес, а также требования к партнеру: наименьший и наибольший возраст, наименьший и наибольший вес, наименьший и наибольший рост. Объединить эти списки в список пар с учетом требований к партнерам без повторений женихов и невест.

19. В библиотеке имеется список книг. Каждая запись этого списка содержит: фамилии авторов, название книги, год издания. Вывести информацию о книгах, в названии которых встречается некоторое ключевое слово (ввести с клавиатуры).

20. В магазине имеется список поступивших в продажу автомобилей. Каждая запись этого списка содержит: марку автомобиля, стоимость, расход топлива на 100 км, надежность (число лет безотказной работы), комфортность (отличная, хорошая, удовлетворительная). Вывести перечень автомобилей, удовлетворяющих требованиям покупателя, которые вводятся с клавиатуры в виде некоторого интервала допустимых значений.

21. Каждая запись списка вакантных рабочих мест содержит: наименование организации, должность, квалификацию (разряд или образование), стаж работы по специальности, заработную плату, наличие социального страхования (да/нет), продолжительность ежегодного оплачиваемого отпуска. Вывести список рабочих мест в соответствии с требованиями клиента.

22. В технической службе аэропорта имеется справочник, содержащий записи следующей структуры: тип самолета, год выпуска, расход горючего на 1000 км. Для определения потребности в горючем техническая служба запрашивает расписание полетов. Каждая запись расписания содержит следующую информацию: номер рейса, пункт назначения, дальность полета. Вывести суммарное количество горючего, необходимое для обеспечения полетов на следующие сутки.

23. Поля шахматной доски характеризуются записью

Type

Pole=record

Ver:(a, b,c, d,e, f,g, h); {вертикальные координаты}

Hor:1..8; {горизонтальные координаты}

end;

Вывести шахматную доску, пометив крестиками все поля, которые «бьет» ферзь, стоящий на поле с координатами Ver и Hor, и ноликами — остальные поля.

24. Поля шахматной доски характеризуются записью (см. задание 23)

Var Figura:Pole;

Вывести сообщение, может ли конь за один ход перейти с поля Figurai на поле Figuraj.

25. Type

Karta=record

m: (piki, trefi, bubni, chervi); {масть}

d:(shest, sem, vosem, devjat, desjat, valet, dama, korol, tuz); {достоинство}

end;

Var k1,k2:Karta;

Вывести сообщение, «бьет» ли карта k1 карту k2, с учетом того что масть mi является козырной.

26. Для участия в конкурсе на замещение вакантной должности сотрудника фирмы желающие подают следующую информацию: Ф. И.О., год рождения, образование(среднее, специальное, высшее), знание иностранных языков(английский, немецкий, французский, владею свободно, читаю и перевожу со словарем), владение компьютером (MSDOS, Windows), стаж работы, наличие рекомендаций. Вывести список претендентов в соответствии с требованиями руководства фирмы.

27. При постановке на учет в ГАИ автолюбители указывают следующие данные: марка автомобиля, год выпуска, номер двигателя, номер кузова, цвет, номерной знак, Ф. И.О и адрес владельца. Вывести список автомобилей, проходящих техосмотр в текущем году, сгруппированных по маркам автомобилей. Учесть, что если текущий год четный, техосмотр проходят автомобили с четными номерами двигателей, иначе – с нечетными номерами.

28. Для участия в конкурсе исполнителей необходимо заполнить следующую анкету: Ф. И.О., год рождения, название страны, класс музыкального инструмента(гитара, фортепиано, скрипка, виолончель). Вывести список самых молодых лауреатов конкурса по классам инструментов в порядке занятых мест.

29. Список группы студентов содержит следующую информацию: Ф. И.О., рост и вес. Вывести Ф. И.О. студентов, рост и вес которых чаще всего встречаются в списке.

30. Список группы студентов содержит следующую информацию: Ф. И.О., рост и вес. Вывести Ф. И.О. студентов, рост и вес которых являются в списке уникальными.

Тема 7. Программирование с использованием подпрограмм и модулей

Цель лабораторной работы: изучить возможности DELPHI для написания подпрограмм и создания модулей. Составить и отладить программу, использующую внешний модуль UNIT с подпрограммой.

7.1. Использование подпрограмм

Подпрограмма – это именованная, определенным образом оформленная группа операторов, которая может быть вызвана любое количество раз из любой точки основной программы.

Подпрограммы используются в том случае, когда одна и та же последовательность операторов в тексте программы повторяется несколько раз. Эта последовательность заменяется вызовом подпрограммы, содержащей необходимые операторы. Подпрограммы также применяются для создания специализированных библиотечных модулей, содержащих набор подпрограмм определенного назначения, для использования их другими программистами.

Подпрограммы подразделяются на процедуры и функции.

Процедура имеет следующую структуру:

Procedure <имя процедуры> ([список формальных параметров]);

Const [описание используемых констант];

Type [описание используемых типов];

Var [описание используемых переменных];

Begin

… // Операторы

End;

В отличие от процедур функции могут использоваться в выражениях в качестве операнда, поэтому они имеют следующую структуру:

Function <имя функции> ([список формальных параметров]): <тип результата>;

Const [описание используемых констант];

Type [описание используемых типов];

Var [описание используемых переменных];

Begin

… // Операторы

Result:= … ; // Занесение результата вычислений в Result

End;

Процедуры и функции могут быть использованы в качестве формальных параметров подпрограмм. Для этого определяется тип:

Type <имя> = function ([список формальных параметров]):<тип результата>;

или Type <имя> = procedure ([список формальных параметров]);.

Имя процедуры или функции должно быть уникальным в пределах программы. Список формальных параметров необязателен и может отсутствовать. Если же он есть, то в нем перечисляются через точку с запятой имена формальных параметров и их типы. Имеется три вида формальных параметров: параметры-значения, параметры-переменные, параметры-константы. При вызове подпрограммы передача данных для этих видов осуществляется по-разному. Параметры-значения копируются, и подпрограмма работает с их копией, поэтому при вызове на месте такого параметра можно ставить арифметическое выражение. При использовании параметров-переменных (в описании перед ними ставится Var) и параметров-констант в подпрограмму передается адрес и она работает с самой переменной. С помощью параметров-переменных подпрограмма передает результаты своей работы вызывающей программе.

В функциях используется специальная переменная Result, интерпретируемая как значение, которое вернет в основную программу функция по окончании своей работы.

В язык Object Pascal встроен ряд наиболее часто употребляемых процедур и функций, которые являются частью языка и вызываются без предварительного определения в разделе описаний.

7.2. Использование модулей

Модуль – автономно компилируемая программная единица, включающая в себя процедуры, функции, а также различные компоненты раздела описаний. Структура модуля представлена в п.1.2 и содержит следующие основные части: заголовок, интерфейсная часть, исполняемая, инициирующая и завершающая.

Заголовок состоит из зарезервированного слова Unit и следующего за ним имени модуля, которое должно совпадать с именем дискового файла. Использование имени модуля в разделе Uses основной программы приводит к установлению связи модуля с основной программой.

Интерфейсная часть расположена между зарезервированными словами interface и implementation и содержит объявление тех объектов модуля, которые должны быть доступны другим программам.

Исполняемая часть начинается зарезервированным словом implementation и содержит описание процедур и функций, объявленных в интерфейсной части. Она может также содержать вспомогательные типы, константы, переменные, процедуры и функции, которые будут использоваться только в исполняемой части и не будут доступны внешним программам.

Инициирующая часть начинается зарезервированным словом initialization и содержит операторы, которые исполняются до передачи управления основной программе.

Завершающая часть начинается зарезервированным словом finalization и выполняется в момент окончания работы программы.

Инициирующая и завершающая части модуля используются крайне редко.

7.3. Порядок выполнения задания

Задание: написать программу вывода на экран таблицы функции, которую оформить в виде процедуры. В качестве функции использовать по выбору Tg(x), ch(x) и sin2(x).

7.3.1. Создание модуля

Создавая модуль, следует обратить внимание на то, что он не должен иметь своей формы. Система DELPHI при начальной загрузке автоматически создает шаблон программы, имеющий в своем составе форму, файл проекта и т. д. Т. к. модуль состоит только из одного файла, то необходимо перед его созданием уничтожить заготовку файла проекта и форму. Для этого в меню File выбрать Close All, файл проекта не сохранять.

Для создания модуля в меню File выбрать File New, и затем в репозитории — пиктограмму . В результате будет создан файл с заголовком Unit Unit1. Имя модуля можно сменить на другое, отвечающее внутреннему содержанию модуля, например Unit Matfu;. Затем необходимо сохранить файл с именем, совпадающим с именем заголовка модуля: Matfu. pas. Следует обратить внимание на то, что имя файла должно совпадать с именем модуля, иначе DELPHI не сможет подключить его к другой программе.

7.3.2. Подключение модуля

Для того чтобы подключить модуль к проекту, необходимо в меню Project выбрать опцию Add to Project… и выбрать файл, содержащий модуль. После этого в разделе Uses добавить имя подключаемого модуля – MatFu. Теперь в проекте можно использовать функции, содержащиеся в модуле.

Панель диалога будет иметь следующий вид (рис. 7.1).

Тексты модуля и вызывающей программы приведены ниже.

Текст модуля:

unit Matfu;

interface

Function Tg(x:extended) : extended; // Функция для вычисления тангенса

Function Ch(x:extended) : extended; // Функция для вычисления гиперболического синуса

Function Sin2(x:extended) : extended; // Функция для вычисления квадрата синуса

implementation

Function Tg;

begin

Result:=Sin(x)/Cos(x);

end;

Function Ch;

begin

Result:=(exp(x)-exp(-x))/2;

end;

Function Sin2;

begin

Result:=sqr(sin(x));

end;

end.

Текст вызывающей программы:

unit Unit1;

interface

uses

Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,

StdCtrls, Buttons, ExtCtrls, MatFu;

type

TForm1 = class(TForm)

Label1: TLabel;

Label2: TLabel;

Label3: TLabel;

Edit1: TEdit;

Edit2: TEdit;

Edit3: TEdit;

Memo1: TMemo;

BitBtn1: TBitBtn;

BitBtn2: TBitBtn;

RadioGroup1: TRadioGroup;

procedure FormCreate(Sender: TObject);

procedure BitBtn1Click(Sender: TObject);

private

{ Private declarations }

public

{ Public declarations }

end;

Type

fun = function(x:extended):extended; // Объявление типа функция

var

Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.FormCreate(Sender: TObject);

begin

Edit1.Text:=’0′;

Edit2.Text:=’3′;

Edit3.Text:=’0,3′;

Memo1.Clear;

RadioGroup1.ItemIndex:=0;

end;

procedure Tabl(f:fun;xn, xk, h:extended); // Расчет таблицы

var x, y: extended;

begin

x:=xn;

repeat

y:=f(x);

Form1.Memo1.Lines. Add(‘x=’+FloatToStrf(x, fffixed,8,3)+

‘ y=’+FloatToStrf(y, fffixed,8,3));

x:=x+h;

until (x>xk);

end;

procedure TForm1.BitBtn1Click(Sender: TObject);

var xn, xk, h : extended;

begin

xn:=StrToFloat(Edit1.Text); // Начальное занчение интервала

xk:=StrToFloat(Edit2.Text); // Конечное значение интервала

h:=StrToFloat(Edit3.Text); // Шаг расчета

case RadioGroup1.ItemIndex of // Выбор функции

0 : Tabl(tg, xn, xk, h);

1 : Tabl(ch, xn, xk, h);

2 : Tabl(sin2,xn, xk, h);

end;

end;

end.

7.4. Выполнение индивидуального задания

По указанию преподавателя выберите вариант задачи из заданий, приведенных в теме 3. Предусмотрите возможность выбора функции, для которой будет рассчитываться таблица. Функции поместите в отдельный модуль. Вызывать выбранную функцию должна процедура, использующая в качестве входного параметра имя соответствующей функции.

Тема 8. Программирование с использованием средств для отображения графической информации

Цель лабораторной работы: изучить возможности построения графиков с помощью компонента отображения графической информации TСhart. Написать и отладить программу построения на экране графика заданной функции.

8.1. Как строится график с помощью компонента TChart

Обычно результаты расчетов представляются в виде графиков и диаграмм. Система DELPHI имеет мощный пакет стандартных программ вывода на экран и редактирования графической информации, который реализуется с помощью визуально отображаемого на форме компонента TChart (рис. 8.1).

Построение графика (диаграммы) производится после вычисления таблицы значений функции y=f(x) на интервале [Xmin, Xmax]с заданным шагом. Полученная таблица передается в специальный двумерный массив Seriesk (k – номер графика) компонента TСhart с помощью метода Add. Компонент PChart осуществляет всю работу по отображению графиков, переданных в объект Seriesk: строит и размечает оси, рисует координатную сетку, подписывает название осей и самого графика, отображает переданную таблицу в виде всевозможных графиков или диаграмм. При необходимости, с помощью встроенного редактора EditingChart компоненту TСhart передаются данные о толщине, стиле и цвете линий, параметрах шрифта подписей, шагах разметки координатной сетки и другие настройки. В процессе работы программы изменение параметров возможно через обращение к соответствующим свойствам компонента TChart. Так, например, свойство Chart1.BottomAxis содержит значение максимального предела нижней оси графика и при его изменении во время работы программы автоматически изменяется изображение графика (см. нижеприведенную программу).

8.2. Пример написания программы

Задание: составить программу, отображающую графики функций sin(x) и cos(x) на интервале [Xmin, Xmax]. Предусмотреть возможность изменения разметки координатных осей, а также шага построения таблицы.

8.2.1. Настройка формы

Панель диалога программы организуется в виде, представленном на рис.8.1.

Для ввода исходных данных используются окна TEdit. Компонент TChart вводится в форму путем нажатия пиктограммы в меню компонентов Standard.

8.2.2. Работа с компонентом TChart

Для изменения параметров компонента TChart необходимо дважды щелкнуть по нему мышью в окне формы. Появится окно редактирования EditingChat1 ( рис. 8.2). Для создания нового объекта Series1 щелкнуть по кнопке Add на странице Series. В появившемся диалоговом окне TeeChart Gallery выбрать пиктограмму с надписью Line (график выводится в виде линий). Если нет необходимости представления графика в трехмерном виде, отключить независимый переключатель 3D. После нажатия на кнопку OK появится новая серия с название Series1. Для изменения названия нажать кнопку Title… В появившемся однострочном редакторе набрать имя отображаемой функции — “sin(x)”. Аналогичным образом создать объект Series2 для функции cos(x).

Для изменения надписи над графиком на странице Titles в многострочном редакторе набрать: “Графики функций”.

Для разметки осей выбрать страницу Axis и научиться устанавливать параметры настройки осей.

Нажимая различные кнопки меню, познакомиться с другими возможностями EditingChat.

8.2.3. Написание программы обработки события создания формы

В данном месте программы устанавливаются начальные пределы и шаг разметки координатных осей. Когда свойство Chart1.BottomAxis. Automatic имеет значения False, автоматическая установка параметров осей не работает.

8.2.4. Написание программ обработки событий нажатия на кнопки

Процедура TForm1.Button1Click обрабатывает нажатие кнопки “Установить оси”. Процедура TForm1.Button2Click обрабатывает нажатие кнопки “Построить график”. Для добавления координат точек (X, Y) из таблицы значений в двумерный массив объекта Seriesk используется процедура Series1.AddXY(Const AXValue, AYValue: Double; Const AXLabel: String; AColor: TColor) : Longint;, где AXValue, AYValue – координаты точки по осям X и Y; AXLabel может принимать значение ‘’; AСolor задает цвет линий (если равен clTeeColor, то принимается цвет, определенный при проектировании формы).

Текст программы имеет вид:

unit tem8;

interface

uses

Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,

ExtCtrls, TeeProcs, TeEngine, Chart, Buttons, StdCtrls, Series;

type

TForm1 = class(TForm)

Edit1: TEdit;

Label1: TLabel;

Label2: TLabel;

Label3: TLabel;

Label4: TLabel;

Label5: TLabel;

Edit2: TEdit;

Edit3: TEdit;

Edit4: TEdit;

Edit5: TEdit;

Button1: TButton;

Button2: TButton;

BitBtn1: TBitBtn;

Chart1: TChart;

Series2: TLineSeries;

Label6: TLabel;

Edit6: TEdit;

Label7: TLabel;

Edit7: TEdit;

Series1: TLineSeries;

procedure FormCreate(Sender: TObject);

procedure Button1Click(Sender: TObject);

procedure Button2Click(Sender: TObject);

private

{ Private declarations }

public

{ Public declarations }

end;

var

Form1: TForm1;

Xmin, Xmax, Ymin, Ymax, Hx, Hy, h : extended;

implementation

{$R *.DFM}

procedure TForm1.FormCreate(Sender: TObject);

begin

{Установка начальных параметров координатных осей}

Xmin:=0;

Xmax:=2*pi;

Ymin:=-1;

Ymax:=1;

Hx:=pi/2;

Hy:=0.5;

h:=0.01; // Установка шага расчета таблицы

{Вывод данных в окна однострочных редакторов}

Edit1.Text:=FloatToStr(Xmin);

Edit2.Text:=FloatToStr(Xmax);

Edit3.Text:=FloatToStr(Ymin);

Edit4.Text:=FloatToStr(Ymax);

Edit5.Text:=FloatToStr(Hx);

Edit6.Text:=FloatToStr(Hy);

Edit7.Text:=FloatToStr(h);

Chart1.BottomAxis. Automatic:=False;// Отключение автоматического определения // параметров нижней оси

Chart1.BottomAxis. Minimum:=Xmin; // Установка левой границы нижней оси

Chart1.BottomAxis. Maximum:=Xmax; // Установка правой границы нижней оси

Chart1.LeftAxis. Automatic:=False; // Отключение автоматического определения // параметров левой оси

Chart1.LeftAxis. Minimum:=Ymin; // Установка нижней границы левой оси

Chart1.LeftAxis. Maximum:=Ymax; // Установка верхней границы левой оси

Chart1.BottomAxis. Increment:=Hx; // Установка шага разметки по нижней оси

Chart1.LeftAxis. Increment:=Hy; // Установка шага разметки по левой оси

end;

procedure TForm1.Button1Click(Sender: TObject);

begin

{Чтение даннных из окон однострочных редакторов}

Xmin:=StrToFloat(Edit1.Text);

Xmax:=StrToFloat(Edit2.Text);

Ymin:=StrToFloat(Edit3.Text);

Ymax:=StrToFloat(Edit4.Text);

Hx:=StrToFloat(Edit5.Text);

Hy:=StrToFloat(Edit6.Text);

Chart1.BottomAxis. Minimum:=Xmin; // Установка левой границы нижней оси

Chart1.BottomAxis. Maximum:=Xmax; // Установка правой границы нижней оси

Chart1.LeftAxis. Minimum:=Ymin; // Установка нижней границы левой оси

Chart1.LeftAxis. Maximum:=Ymax; // Установка верхней границы левой оси

Chart1.BottomAxis. Increment:=Hx; // Установка шага разметки по нижней оси

Chart1.LeftAxis. Increment:=Hy; // Установка шага разметки по левой оси

end;

procedure TForm1.Button2Click(Sender: TObject);

var x, y1,y2: extended;

begin

{Очистка графиков}

Series1.Clear;

Series2.Clear;

Xmin:=StrToFloat(Edit1.Text);

Xmax:=StrToFloat(Edit2.Text);

h:=StrToFloat(Edit7.Text); // Шаг расчета таблицы для графика

x:=Xmin; // Начальное значение по оси X

repeat

y1:=sin(x); // Расчет функции

Series1.AddXY(x, y1,»,clTeeColor); // Вывод точки на график

y2:=cos(x); // Расчет функции

Series2.AddXY(x, y2,»,clTeeColor); // Вывод точки на график

x:=x+h; // Увеличение значения X на величину шага

Until (x>Xmax);

end;

end.

8.3. Выполнение индивидуального задания

Постройте графики функций для соответствующих вариантов из темы №1. Таблицу данных получить изменяя параметр X с шагом h. Ввод исходных данных организовать через окна TEdit. Самостоятельно выбрать удобные параметры настройки.